147 lines
6 KiB
VHDL
147 lines
6 KiB
VHDL
|
|
-- Virtual processor with Avalon memory mapped master BFM, based on VProc co-simulation element.
|
|
|
|
library ieee;
|
|
use ieee.std_logic_1164.all;
|
|
use ieee.numeric_std.all;
|
|
|
|
entity avsvproc_waitreq is
|
|
generic (
|
|
NODE_NUM : integer := 0;
|
|
SEQ_PAGE : std_logic_vector(3 downto 0) := 4x"4";
|
|
AUTO_VALID_CSR : boolean := false;
|
|
WR_LENGTH : integer := 1;
|
|
RD_LENGTH : integer := 3
|
|
);
|
|
port (
|
|
clk : in std_logic;
|
|
rst_n : in std_logic;
|
|
|
|
-- Avalon memory mapped master interface
|
|
avs_csr_address : out std_logic_vector(31 downto 0);
|
|
avs_csr_write : out std_logic;
|
|
avs_csr_writedata : out std_logic_vector(31 downto 0);
|
|
avs_csr_read : out std_logic;
|
|
avs_csr_readdata : in std_logic_vector(31 downto 0) := (others => '0');
|
|
avs_csr_readdatavalid : in std_logic := '0';
|
|
|
|
-- Avalon memory mapped master interface
|
|
avs_seq_address : out std_logic_vector(31 downto 0);
|
|
avs_seq_write : out std_logic;
|
|
avs_seq_writedata : out std_logic_vector(31 downto 0);
|
|
avs_seq_read : out std_logic;
|
|
avs_seq_readdata : in std_logic_vector(31 downto 0) := (others => '0');
|
|
avs_seq_readdatavalid : in std_logic := '0';
|
|
|
|
-- Interrupt
|
|
irq : in std_logic := '0'
|
|
);
|
|
end entity;
|
|
|
|
architecture behavioural of avsvproc_waitreq is
|
|
|
|
-- Signals for VProc
|
|
signal update : std_logic;
|
|
signal RD : std_logic;
|
|
signal RDLast : std_logic;
|
|
signal Addr : std_logic_vector(31 downto 0);
|
|
signal WE : std_logic;
|
|
signal DataOut : std_logic_vector(31 downto 0);
|
|
signal DataIn : std_logic_vector(31 downto 0);
|
|
signal RDAck : std_logic;
|
|
signal WRAck : std_logic;
|
|
|
|
-- Avalon bus protocol signals
|
|
signal sel_seq_bus : std_logic;
|
|
signal avs_read : std_logic;
|
|
|
|
signal avs_csr_readdatavalid_int : std_logic_vector(RD_LENGTH downto 0);
|
|
signal avs_csr_writedatavalid_int: std_logic_vector(WR_LENGTH downto 0);
|
|
|
|
begin
|
|
|
|
-- If auto-generation of read valid for CSR bus is selected, generate x cycles after avs_csr_read
|
|
GEN_AUTO_VALID_CSR : if AUTO_VALID_CSR generate
|
|
-- Generate a read data valid for the CSR bus, as the UUT does not do so
|
|
PROC_CSR_RDVALID : process(clk, rst_n)
|
|
begin
|
|
if rst_n = '0' then
|
|
avs_csr_readdatavalid_int <= (others => '0');
|
|
avs_csr_writedatavalid_int <= (others => '0');
|
|
elsif clk'event and clk = '1' then
|
|
avs_csr_readdatavalid_int <= avs_csr_readdatavalid_int(avs_csr_readdatavalid_int'LENGTH-2 downto 0) & '0';
|
|
avs_csr_writedatavalid_int <= avs_csr_writedatavalid_int(avs_csr_writedatavalid_int'LENGTH-2 downto 0) & '0';
|
|
if avs_csr_read = '1' and to_integer(unsigned(avs_csr_readdatavalid_int)) = 0 then
|
|
avs_csr_readdatavalid_int(0) <= '1';
|
|
end if;
|
|
if avs_csr_write = '1' and to_integer(unsigned(avs_csr_writedatavalid_int)) = 0 then
|
|
avs_csr_writedatavalid_int(0) <= '1';
|
|
end if;
|
|
end if;
|
|
end process;
|
|
|
|
end generate;
|
|
|
|
-- If auto-generation of read valid for CSR bus is not selected, connect up the input port
|
|
GEN_NOT_AUTO_VALID_CSR : if not AUTO_VALID_CSR generate
|
|
avs_csr_readdatavalid_int <= (others => avs_csr_readdatavalid);
|
|
avs_csr_writedatavalid_int <= (others => WE);
|
|
end generate;
|
|
|
|
-- Flag if the VProc address selects the sequencer buffers page
|
|
sel_seq_bus <= '1' when Addr(19 downto 16) = SEQ_PAGE else '0';
|
|
|
|
-- Mux the busses based on the sequencer buff page flag.
|
|
-- Note. VProc produces byte addresses, but bus is 32 bit word addresses
|
|
avs_csr_read <= RD and not sel_seq_bus;
|
|
avs_csr_write <= WE and not sel_seq_bus;
|
|
avs_csr_writedata <= DataOut when sel_seq_bus = '0' else (others => '0');
|
|
avs_csr_address <= "00" & Addr(31 downto 2) when sel_seq_bus = '0' else (others => '0');
|
|
|
|
avs_seq_read <= avs_read and sel_seq_bus;
|
|
avs_seq_write <= WE and sel_seq_bus;
|
|
avs_seq_writedata <= DataOut when sel_seq_bus = '1' else (others => '0');
|
|
avs_seq_address <= "00" & Addr(31 downto 2) when sel_seq_bus = '1' else (others => '0');
|
|
|
|
DataIn <= avs_csr_readdata when sel_seq_bus = '0' else avs_seq_readdata;
|
|
RDAck <= avs_csr_readdatavalid_int(avs_csr_readdatavalid_int'LENGTH-2) when sel_seq_bus = '0' else avs_seq_readdatavalid;
|
|
WRAck <= avs_csr_writedatavalid_int(avs_csr_writedatavalid_int'LENGTH-2) when sel_seq_bus = '0' else WE;
|
|
|
|
-----------------------------------------
|
|
-- VProc instantiation
|
|
-----------------------------------------
|
|
|
|
vproc_inst : entity work.VProc
|
|
port map (
|
|
Clk => clk,
|
|
Addr => Addr,
|
|
WE => WE,
|
|
RD => RD,
|
|
DataOut => DataOut,
|
|
DataIn => DataIn,
|
|
WRAck => WRAck,
|
|
RDAck => RDAck,
|
|
Interrupt => "00" & irq,
|
|
Update => update,
|
|
UpdateResponse => update,
|
|
Node => std_logic_vector(to_unsigned(NODE_NUM, 4))
|
|
);
|
|
|
|
-----------------------------------------
|
|
-- Generate a delayed version of the RD
|
|
-- output of VProc
|
|
-----------------------------------------
|
|
process(clk, rst_n)
|
|
begin
|
|
if rst_n = '0' then
|
|
RDLast <= '0';
|
|
elsif clk'event and clk = '1' then
|
|
RDLast <= RD;
|
|
end if;
|
|
end process;
|
|
|
|
-- Pulse the AVS read signal only for the first cycles of RD, which won't be
|
|
-- deasserted until the RDAck/avs_readdatavalid is returned.
|
|
avs_read <= RD and not RDLast;
|
|
|
|
end behavioural;
|